1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
|
/* Copyright (C) 2002, 2003, 2007 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <lowlevellock.h>
#include <lowlevelrwlock.h>
#include <pthread-errnos.h>
#include <bits/kernel-features.h>
#include <tls.h>
.text
.globl __pthread_rwlock_rdlock
.type __pthread_rwlock_rdlock,@function
.align 16
__pthread_rwlock_rdlock:
cfi_startproc
pushl %esi
cfi_adjust_cfa_offset(4)
pushl %ebx
cfi_adjust_cfa_offset(4)
cfi_offset(%esi, -8)
cfi_offset(%ebx, -12)
xorl %esi, %esi
movl 12(%esp), %ebx
/* Get the lock. */
movl $1, %edx
xorl %eax, %eax
LOCK
#if MUTEX == 0
cmpxchgl %edx, (%ebx)
#else
cmpxchgl %edx, MUTEX(%ebx)
#endif
jnz 1f
2: movl WRITER(%ebx), %eax
testl %eax, %eax
jne 14f
cmpl $0, WRITERS_QUEUED(%ebx)
je 5f
cmpb $0, FLAGS(%ebx)
je 5f
3: addl $1, READERS_QUEUED(%ebx)
je 4f
movl READERS_WAKEUP(%ebx), %edx
LOCK
#if MUTEX == 0
subl $1, (%ebx)
#else
subl $1, MUTEX(%ebx)
#endif
jne 10f
11:
#ifdef __ASSUME_PRIVATE_FUTEX
movzbl PSHARED(%ebx), %ecx
xorl $FUTEX_PRIVATE_FLAG|FUTEX_WAIT, %ecx
#else
movzbl PSHARED(%ebx), %ecx
# if FUTEX_WAIT != 0
orl $FUTEX_WAIT, %ecx
# endif
xorl %gs:PRIVATE_FUTEX, %ecx
#endif
addl $READERS_WAKEUP, %ebx
movl $SYS_futex, %eax
ENTER_KERNEL
subl $READERS_WAKEUP, %ebx
/* Reget the lock. */
movl $1, %edx
xorl %eax, %eax
LOCK
#if MUTEX == 0
cmpxchgl %edx, (%ebx)
#else
cmpxchgl %edx, MUTEX(%ebx)
#endif
jnz 12f
13: subl $1, READERS_QUEUED(%ebx)
jmp 2b
5: xorl %edx, %edx
addl $1, NR_READERS(%ebx)
je 8f
9: LOCK
#if MUTEX == 0
subl $1, (%ebx)
#else
subl $1, MUTEX(%ebx)
#endif
jne 6f
7:
movl %edx, %eax
popl %ebx
cfi_adjust_cfa_offset(-4)
cfi_restore(%ebx)
popl %esi
cfi_adjust_cfa_offset(-4)
cfi_restore(%esi)
ret
cfi_adjust_cfa_offset(8)
cfi_offset(%esi, -8)
cfi_offset(%ebx, -12)
1:
#if MUTEX == 0
movl %ebx, %edx
#else
leal MUTEX(%ebx), %edx
#endif
movzbl PSHARED(%ebx), %ecx
call __lll_lock_wait
jmp 2b
14: cmpl %gs:TID, %eax
jne 3b
/* Deadlock detected. */
movl $EDEADLK, %edx
jmp 9b
6:
#if MUTEX == 0
movl %ebx, %eax
#else
leal MUTEX(%ebx), %eax
#endif
movzbl PSHARED(%ebx), %ecx
call __lll_unlock_wake
jmp 7b
/* Overflow. */
8: subl $1, NR_READERS(%ebx)
movl $EAGAIN, %edx
jmp 9b
/* Overflow. */
4: subl $1, READERS_QUEUED(%ebx)
movl $EAGAIN, %edx
jmp 9b
10:
#if MUTEX == 0
movl %ebx, %eax
#else
leal MUTEX(%ebx), %eax
#endif
movzbl PSHARED(%ebx), %ecx
call __lll_unlock_wake
jmp 11b
12:
#if MUTEX == 0
movl %ebx, %edx
#else
leal MUTEX(%ebx), %edx
#endif
movzbl PSHARED(%ebx), %ecx
call __lll_lock_wait
jmp 13b
cfi_endproc
.size __pthread_rwlock_rdlock,.-__pthread_rwlock_rdlock
.globl pthread_rwlock_rdlock
pthread_rwlock_rdlock = __pthread_rwlock_rdlock
.globl __pthread_rwlock_rdlock_internal
__pthread_rwlock_rdlock_internal = __pthread_rwlock_rdlock
|