1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
/* Startup code for SH & ELF.
Copyright (C) 1999 Free Software Foundation, Inc.
Copyright (C) 2001 Hewlett-Packard Australia
This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Library General Public License as published by the Free
Software Foundation; either version 2 of the License, or (at your option) any
later version.
This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Library General Public License for more
details.
You should have received a copy of the GNU Library General Public License
along with this program; if not, write to the Free Software Foundation, Inc.,
59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
Derived in part from the Linux-8086 C library, the GNU C Library, and several
other sundry sources. Files within this library are copyright by their
respective copyright holders.
*/
/* This is the canonical entry point, usually the first thing in the text
segment.
At this entry point, most registers' values are unspecified, except:
sp The stack contains the arguments and environment:
0(sp) argc
4(sp) argv[0]
...
(4*argc)(sp) NULL
(4*(argc+1))(sp) envp[0]
...
NULL
*/
.file "crt0.S"
.text
.globl _start
.type _start,@function
.size _start,_start_end - _start
_start:
/* Clear the frame pointer since this is the outermost frame. */
mov #0, r14
/* Pop argc off the stack and save a pointer to argv */
mov.l @r15+,r4
mov r15, r5
#if ! defined __UCLIBC_CTOR_DTOR__
/*
* Setup the value for the environment pointer:
* r6 = (argc + 1) * 4
* r6 += argv (in delay slot)
*/
mov r4,r6
add #1,r6
shll2 r6
add r5, r6
/* jump to __uClibc_main (argc, argv, envp) */
mov.l L_main, r0
jsr @r0
nop /* delay slot */
/* We should not get here. */
mov.l L_abort, r0
jmp @r0
nop
_start_end:
.align 2
L_main:
.long __uClibc_main /* in libuClibc.*.so */
#else /* __UCLIBC_CTOR_DTOR__ */
/* Push the finip argument to __uClibc_start_main() onto the stack */
mov.l L_fini,r6
mov.l r6,@-r15
/* Setup the value for the initp argument */
mov.l L_init, r7
/*
* Setup the value for the environment pointer:
* r6 = (argc + 1) * 4
* r6 += argv (in delay slot)
*/
mov r4,r6
add #1,r6
shll2 r6
/* jump to __uClibc_start_main (argc, argv, envp, app_init, app_fini) */
mov.l L_main, r0
jsr @r0
add r5, r6 /* delay slot */
/* We should not get here. */
mov.l L_abort, r0
jmp @r0
nop
_start_end:
.align 2
L_main:
.long __uClibc_start_main /* in libuClibc.*.so */
.weak _init
.type _init,@function
_init:
rts
nop
.Lfe1:
.size _init,.Lfe1-_init
.weak _fini
.set _fini,_init
L_init:
.long _init
L_fini:
.long _fini
#endif
L_abort:
.long abort
/* Stick in a dummy reference to main(), so that if an application
* is linking when the main() function is in a static library (.a)
* we can be sure that main() actually gets linked in */
L_dummy_main_reference:
.long main
|
