1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
/* Copyright (C) 1991, 1992 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Library General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Library General Public License for more details.
You should have received a copy of the GNU Library General Public
License along with the GNU C Library; see the file COPYING.LIB. If
not, write to the Free Software Foundation, Inc., 675 Mass Ave,
Cambridge, MA 02139, USA. */
/* If you don't know what is going on here, check out
http://linuxassembly.org/startup.html
For a description of the stack layout.
-John Beppu, and Erik Andersen
*/
.global __environ
.global __errno
.global _start
.global exit
.global main
.global __stdio_close_all
.global _void_void_null_func
.global _start_exit
.text
_start:
/* First locate the start of the environment variables */
popl %ecx /* Store argc into %ecx */
movl %esp,%ebx /* Store argv into ebx */
movl %esp,%eax /* Store argv into eax as well*/
movl %ecx,%edx /* Stick argc into %edx so we can do some math in a sec */
leal 4(%eax,%edx,4),%eax
/* [ register layout ]
sizeof(char*) == 4
%ecx = argc ; 0(esp)
%ebx = argv ; 4(esp)
%eax = env ; argv + (argc * 4) + 4
*/
/* Set up an invalid (NULL return address, NULL frame pointer)
callers stack frame so anybody unrolling the stack knows where
to stop */
xorl %ebp,%ebp /* NULL */
pushl %ebp /* callers %cs */
pushl %ebp /* callers %eip (return address) */
pushl %ebp /* callers %ebp (frame pointer) */
movl %esp,%ebp /* mark callers stack frame as invalid */
/* Now set the environment, argc, and argv where the app can get to them */
pushl %eax /* Environment pointer */
pushl %ebx /* Argument pointer */
pushl %ecx /* And the argument count */
/* Make sure we are not using iBCS2 personality. (i.e. force linux). */
movl $136,%eax
sub %ebx,%ebx
int $0x80
/* set up __environ */
movl 8(%esp),%eax
movl %eax,__environ
/* Tell libc to initialize anything it needs to do */
call __libc_init
/* call __malloc_init */
call __init_stdio
/* Ok, now run main() */
call main
pushl %eax
call exit
/* Just in case _exit fails... We use int $0x80 for __exit(). */
popl %ebx
.align 4,0x90
_start_exit:
movl $1,%eax
int $0x80
jmp _start_exit
.align 4,0x90
_void_void_null_func:
ret
.weak __libc_init
__libc_init = _void_void_null_func
/*
.weak __malloc_init
__malloc_init = _void_void_null_func
*/
.weak __init_stdio
__init_stdio = _void_void_null_func
.weak __stdio_close_all
__stdio_close_all = _void_void_null_func
.data
__environ:
.long 0
.weak environ
.align 4
environ = __environ
.data
__errno:
.long 0
.weak errno
.align 4
errno = __errno
|
