1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
/*
* Copyright (C) 2004-2007 Atmel Corporation
*
* This file is subject to the terms and conditions of the GNU Lesser General
* Public License. See the file "COPYING.LIB" in the main directory of this
* archive for more details.
*/
#include <features.h>
#define str r12
.text
.global strlen
.type strlen, @function
strlen:
mov r11, r12
mov r9, str
andl r9, 3, COH
brne .Lunaligned_str
1: ld.w r8, str++
tnbz r8
brne 1b
sub r12, r11
bfextu r9, r8, 24, 8
cp.w r9, 0
subeq r12, 4
reteq r12
bfextu r9, r8, 16, 8
cp.w r9, 0
subeq r12, 3
reteq r12
bfextu r9, r8, 8, 8
cp.w r9, 0
subeq r12, 2
reteq r12
sub r12, 1
retal r12
.Lunaligned_str:
add pc, pc, r9 << 3
sub r0, r0, 0 /* 4-byte nop */
ld.ub r8, str++
sub r8, r8, 0
breq 1f
ld.ub r8, str++
sub r8, r8, 0
breq 1f
ld.ub r8, str++
sub r8, r8, 0
brne 1b
1: sub r12, 1
sub r12, r11
retal r12
.size strlen, . - strlen
libc_hidden_def(strlen)
|
